Icon Donut Chart

This example modifies the Icon Pie Chart example by using a semi-transparent donut instead of a pie, and using metallic background color.

BaseChart.setColors is used to select the default semi-transparent palette transparentPalette. This palette uses semi-transparent data colors instead of the normal data colors.
ChartDirector.CFChart.metalColor is used to create metallic colors using light blue and blue as the base colors. The colors are then used as the chart background color by calling BaseChart.setBackground, and as chart title background color by calling Box.setBackground of the title TextBox object.

[File: cfdemo/icondonut.cfm]

<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// The data for the pie chart
data = Array(72, 18, 15, 12);

// The depths for the sectors
depths = Array(30, 20, 10, 10);

// The labels for the pie chart
labels = Array("Sunny", "Cloudy", "Rainy", "Snowy");

// The icons for the sectors
icons = Array("sun.png", "cloud.png", "rain.png", "snowy.png");

// Create a PieChart object of size 400 x 300 pixels
c = cd.PieChart(400, 300);

// Use the semi-transparent palette for this chart
c.setColors(cd.transparentPalette);

// Set the background to metallic light blue (CCFFFF), with a black border and 1 pixel 3D border
// effect,
c.setBackground(cd.metalColor("0xccccff"), "0x000000", 1);

// Set search path to current directory for loading icon images
c.setSearchPath(GetPageContext());

// Set donut center at (200, 175), and outer/inner radii as 100/50 pixels
c.setDonutSize(200, 175, 100, 50);

// Add a title box using 15pt Times Bold Italic font and metallic blue (8888FF) background color
c.addTitle("Weather Profile in Wonderland", "Times New Roman Bold Italic", 15).setBackground(
    cd.metalColor("0x8888ff"));

// Set the pie data and the pie labels
c.setData(data, labels);

// Add icons to the chart as a custom field
c.addExtraField(icons);

// Configure the sector labels using CDML to include the icon images
c.setLabelFormat(
    "<*block,valign=absmiddle*><*img={field0}*> <*block*>{label}<*br*>{percent}%<*/*><*/*>");

// Draw the pie in 3D with variable 3D depths
c.set3D2(depths);

// Set the start angle to 225 degrees may improve layout when the depths of the sector are sorted in
// descending order, because it ensures the tallest sector is at the back.
c.setStartAngle(225);

// Output the chart
chart1URL = c.makeSession(GetPageContext(), "chart1");

// Include tool tip for the chart
imageMap1 = c.getHTMLImageMap("", "", "title='{label}: {value} days ({percent}%)'");

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Icon Donut Chart
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart1URL#" usemap="##map1" border="0" />
<map name="map1">#imageMap1#</map>
</cfoutput>
</body>
</html>