ChartDirector 6.0 (ASP/COM/VB Edition)

Color Horizontal Bar Meters


          

This example demonstrates horizontal bar meters in various colors, with different color scales, and with title and value readout.

BaseMeter.addColorScale is used to create the color scales in the meters. The color scales are created by with different colors, different end point positions and different widths at the end points.

The title and value readout are created using BaseChart.addText. The value readout is configured to have a black background and a depressed border using Box.setBackground, and with rounded corners using Box.setRoundedCorners.

Source Code Listing

[Web Version (in ASP)] aspdemo\colorhbarmeter.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' This script can draw different charts depending on the chartIndex
chartIndex = CInt(Request("img"))

' The value to display on the meter
value = 75.35

' The background, border and bar colors of the meters
bgColor = Array(&Hbbddff, &Hccffcc, &Hffddff, &Hffffaa, &Hffdddd, &Heeeeee)
borderColor = Array(&H000088, &H006600, &H880088, &Hee6600, &H880000, &H666666)
barColor = Array(&H0088ff, &H00cc00, &H8833dd, &Hff8800, &Hee3333, &H888888)

' Create a LinearMeter object of size 260 x 80 pixels with a 3-pixel thick rounded frame
Set m = cd.LinearMeter(260, 80, bgColor(chartIndex), borderColor(chartIndex))
Call m.setRoundedFrame(cd.Transparent)
Call m.setThickFrame(3)

' Set the scale region top-left corner at (18, 24), with size of 222 x 20 pixels. The scale labels
' are located on the top (implies horizontal meter)
Call m.setMeter(18, 24, 222, 20, cd.Top)

' Set meter scale from 0 - 100, with a tick every 10 units
Call m.setScale(0, 100, 10)

If chartIndex Mod 4 = 0 Then
    ' Add a 5-pixel thick smooth color scale at y = 48 (below the meter scale)
    smoothColorScale = Array(0, &H0000ff, 25, &H0088ff, 50, &H00ff00, 75, &Hdddd00, 100, &Hff0000)
    Call m.addColorScale(smoothColorScale, 48, 5)
ElseIf chartIndex Mod 4 = 1 Then
    ' Add a 5-pixel thick step color scale at y = 48 (below the meter scale)
    stepColorScale = Array(0, &H00cc00, 50, &Hffdd00, 80, &Hff3333, 100)
    Call m.addColorScale(stepColorScale, 48, 5)
ElseIf chartIndex Mod 4 = 2 Then
    ' Add a 5-pixel thick high/low color scale at y = 48 (below the meter scale)
    highLowColorScale = Array(0, &H0000ff, 40, cd.Transparent, 60, cd.Transparent, 100, &Hff0000)
    Call m.addColorScale(highLowColorScale, 48, 5)
Else
    ' Add a 5-pixel thick high only color scale at y = 48 (below the meter scale)
    highColorScale = Array(70, cd.Transparent, 100, &Hff0000)
    Call m.addColorScale(highColorScale, 48, 0, 48, 8)
End If

' Add a bar from 0 to value with glass effect and 4 pixel rounded corners
Call m.addBar(0, value, barColor(chartIndex), cd.glassEffect(cd.NormalGlare, cd.Top), 4)

' Add a label right aligned to (243, 65) using 8pt Arial Bold font
Call m.addText(243, 65, "Temperature C", "arialbd.ttf", 8, cd.TextColor, cd.Right)

' Add a text box left aligned to (18, 65). Display the value using white (0xffffff) 8pt Arial Bold
' font on a black (0x000000) background with depressed rounded border.
Set t = m.addText(18, 65, m.formatValue(value, "2"), "arial.ttf", 8, &Hffffff, cd.Left)
Call t.setBackground(&H000000, &H000000, -1)
Call t.setRoundedCorners(3)

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite m.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\colorhbarmeter.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The value to display on the meter
    Dim value As Double
    value = 75.35

    ' The background, border and bar colors of the meters
    Dim bgColor()
    bgColor = Array(&Hbbddff, &Hccffcc, &Hffddff, &Hffffaa, &Hffdddd, &Heeeeee)
    Dim borderColor()
    borderColor = Array(&H000088, &H006600, &H880088, &Hee6600, &H880000, &H666666)
    Dim barColor()
    barColor = Array(&H0088ff, &H00cc00, &H8833dd, &Hff8800, &Hee3333, &H888888)

    ' Create a LinearMeter object of size 260 x 80 pixels with a 3-pixel thick rounded frame
    Dim m As LinearMeter
    Set m = cd.LinearMeter(260, 80, bgColor(chartIndex), borderColor(chartIndex))
    Call m.setRoundedFrame()
    Call m.setThickFrame(3)

    ' Set the scale region top-left corner at (18, 24), with size of 222 x 20 pixels. The scale
    ' labels are located on the top (implies horizontal meter)
    Call m.setMeter(18, 24, 222, 20, cd.Top)

    ' Set meter scale from 0 - 100, with a tick every 10 units
    Call m.setScale(0, 100, 10)

    If chartIndex Mod 4 = 0 Then
        ' Add a 5-pixel thick smooth color scale at y = 48 (below the meter scale)
        Dim smoothColorScale()
        smoothColorScale = Array(0, &H0000ff, 25, &H0088ff, 50, &H00ff00, 75, &Hdddd00, 100, _
            &Hff0000)
        Call m.addColorScale(smoothColorScale, 48, 5)
    ElseIf chartIndex Mod 4 = 1 Then
        ' Add a 5-pixel thick step color scale at y = 48 (below the meter scale)
        Dim stepColorScale()
        stepColorScale = Array(0, &H00cc00, 50, &Hffdd00, 80, &Hff3333, 100)
        Call m.addColorScale(stepColorScale, 48, 5)
    ElseIf chartIndex Mod 4 = 2 Then
        ' Add a 5-pixel thick high/low color scale at y = 48 (below the meter scale)
        Dim highLowColorScale()
        highLowColorScale = Array(0, &H0000ff, 40, cd.Transparent, 60, cd.Transparent, 100, _
            &Hff0000)
        Call m.addColorScale(highLowColorScale, 48, 5)
    Else
        ' Add a 5-pixel thick high only color scale at y = 48 (below the meter scale)
        Dim highColorScale()
        highColorScale = Array(70, cd.Transparent, 100, &Hff0000)
        Call m.addColorScale(highColorScale, 48, 0, 48, 8)
    End If

    ' Add a bar from 0 to value with glass effect and 4 pixel rounded corners
    Call m.addBar(0, value, barColor(chartIndex), cd.glassEffect(cd.NormalGlare, cd.Top), 4)

    ' Add a label right aligned to (243, 65) using 8pt Arial Bold font
    Call m.addText(243, 65, "Temperature C", "arialbd.ttf", 8, cd.TextColor, cd.Right)

    ' Add a text box left aligned to (18, 65). Display the value using white (0xffffff) 8pt Arial
    ' Bold font on a black (0x000000) background with depressed rounded border.
    Dim t As ChartDirector.TextBox
    Set t = m.addText(18, 65, m.formatValue(value, "2"), "arial.ttf", 8, &Hffffff, cd.Left)
    Call t.setBackground(&H000000, &H000000, -1)
    Call t.setRoundedCorners(3)

    ' Output the chart
    Set viewer.Picture = m.makePicture()

End Sub