ChartDirector 6.0 (ASP/COM/VB Edition)

Color Vertical Bar Meters


          

This example demonstrates horizontal bar meters in various colors, with different color scales, and with title and value readout.

BaseMeter.addColorScale is used to create the color scales in the meters. The color scales are created with various colors, end point positions and widths at the end points.

The title and value readout are created as TextBox objects using BaseChart.addTitle and BaseChart.addTitle2, with the text box background set to the same color as that of the chart border.

Source Code Listing

[Web Version (in ASP)] aspdemo\colorvbarmeter.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' This script can draw different charts depending on the chartIndex
chartIndex = CInt(Request("img"))

' The value to display on the meter
value = 66.77

' The background, border and bar colors of the meters
bgColor = Array(&Hcce4ff, &Hccffcc, &Hffdddd, &Hffffaa, &Hffccff, &Heeeeee)
borderColor = Array(&H000088, &H006600, &H880000, &Hee6600, &H6600aa, &H666666)
barColor = Array(&H2299ff, &H00ee00, &Hee4455, &Hff8800, &H8833dd, &H888888)

' Create a LinearMeter object of size 70 x 260 pixels with a 3-pixel thick rounded frame
Set m = cd.LinearMeter(70, 260, bgColor(chartIndex), borderColor(chartIndex))
Call m.setRoundedFrame(cd.Transparent)
Call m.setThickFrame(3)

' Set the scale region top-left corner at (28, 33), with size of 20 x 194 pixels. The scale labels
' are located on the left (default - implies vertical meter).
Call m.setMeter(28, 33, 20, 194)

' Set meter scale from 0 - 100, with a tick every 10 units
Call m.setScale(0, 100, 10)

' Demostrate different types of color scales
smoothColorScale = Array(0, &H0000ff, 25, &H0088ff, 50, &H00ff00, 75, &Hdddd00, 100, &Hff0000)
stepColorScale = Array(0, &H33ff33, 50, &Hffff00, 80, &Hff3333, 100)
highLowColorScale = Array(0, &H0000ff, 40, cd.Transparent, 60, cd.Transparent, 100, &Hff0000)
highColorScale = Array(70, cd.Transparent, 100, &Hff0000)
lowColorScale = Array(0, &H0000ff, 30, cd.Transparent)

If chartIndex = 0 Then
    ' Add a 6-pixel thick smooth color scale at x = 53 (right of meter scale)
    Call m.addColorScale(smoothColorScale, 53, 6)
ElseIf chartIndex = 1 Then
    ' Add a high only color scale at x = 52 (right of meter scale) with thickness varying from 0 to
    ' 8
    Call m.addColorScale(highColorScale, 52, 0, 52, 8)
    ' Add a low only color scale at x = 52 (right of meter scale) with thickness varying from 8 to 0
    Call m.addColorScale(lowColorScale, 52, 8, 52, 0)
ElseIf chartIndex = 2 Then
    ' Add a high only color scale at x = 52 (right of meter scale) with thickness varying from 0 to
    ' 8
    Call m.addColorScale(highColorScale, 52, 0, 52, 8)
ElseIf chartIndex = 3 Then
    ' Add a smooth color scale at x = 52 (right of meter scale) with thickness varying from 0 to 8
    Call m.addColorScale(smoothColorScale, 52, 0, 52, 8)
ElseIf chartIndex = 4 Then
    ' Add a 6-pixel thick high/low color scale at x = 53 (right of meter scale)
    Call m.addColorScale(highLowColorScale, 53, 6)
Else
    ' Add a 6-pixel thick step color scale at x = 53 (right of meter scale)
    Call m.addColorScale(stepColorScale, 53, 6)
End If

' Add a bar from 0 to value with glass effect and 4 pixel rounded corners
Call m.addBar(0, value, barColor(chartIndex), cd.glassEffect(cd.NormalGlare, cd.Left), 4)

' Add a title using white (0xffffff) 8pt Arial Bold font with a border color background
Call m.addTitle("Temp C", "arialbd.ttf", 8, &Hffffff).setBackground(borderColor(chartIndex))

' Add a bottom title using white (0xffffff) 8pt Arial Bold font with a border color background to
' display the value
Call m.addTitle2(cd.Bottom, m.formatValue(value, "2"), "arialbd.ttf", 8, &Hffffff).setBackground( _
    borderColor(chartIndex))

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite m.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\colorvbarmeter.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The value to display on the meter
    Dim value As Double
    value = 66.77

    ' The background, border and bar colors of the meters
    Dim bgColor()
    bgColor = Array(&Hcce4ff, &Hccffcc, &Hffdddd, &Hffffaa, &Hffccff, &Heeeeee)
    Dim borderColor()
    borderColor = Array(&H000088, &H006600, &H880000, &Hee6600, &H6600aa, &H666666)
    Dim barColor()
    barColor = Array(&H2299ff, &H00ee00, &Hee4455, &Hff8800, &H8833dd, &H888888)

    ' Create a LinearMeter object of size 70 x 260 pixels with a 3-pixel thick rounded frame
    Dim m As LinearMeter
    Set m = cd.LinearMeter(70, 260, bgColor(chartIndex), borderColor(chartIndex))
    Call m.setRoundedFrame()
    Call m.setThickFrame(3)

    ' Set the scale region top-left corner at (28, 33), with size of 20 x 194 pixels. The scale
    ' labels are located on the left (default - implies vertical meter).
    Call m.setMeter(28, 33, 20, 194)

    ' Set meter scale from 0 - 100, with a tick every 10 units
    Call m.setScale(0, 100, 10)

    ' Demostrate different types of color scales
    Dim smoothColorScale()
    smoothColorScale = Array(0, &H0000ff, 25, &H0088ff, 50, &H00ff00, 75, &Hdddd00, 100, &Hff0000)
    Dim stepColorScale()
    stepColorScale = Array(0, &H33ff33, 50, &Hffff00, 80, &Hff3333, 100)
    Dim highLowColorScale()
    highLowColorScale = Array(0, &H0000ff, 40, cd.Transparent, 60, cd.Transparent, 100, &Hff0000)
    Dim highColorScale()
    highColorScale = Array(70, cd.Transparent, 100, &Hff0000)
    Dim lowColorScale()
    lowColorScale = Array(0, &H0000ff, 30, cd.Transparent)

    If chartIndex = 0 Then
        ' Add a 6-pixel thick smooth color scale at x = 53 (right of meter scale)
        Call m.addColorScale(smoothColorScale, 53, 6)
    ElseIf chartIndex = 1 Then
        ' Add a high only color scale at x = 52 (right of meter scale) with thickness varying from 0
        ' to 8
        Call m.addColorScale(highColorScale, 52, 0, 52, 8)
        ' Add a low only color scale at x = 52 (right of meter scale) with thickness varying from 8
        ' to 0
        Call m.addColorScale(lowColorScale, 52, 8, 52, 0)
    ElseIf chartIndex = 2 Then
        ' Add a high only color scale at x = 52 (right of meter scale) with thickness varying from 0
        ' to 8
        Call m.addColorScale(highColorScale, 52, 0, 52, 8)
    ElseIf chartIndex = 3 Then
        ' Add a smooth color scale at x = 52 (right of meter scale) with thickness varying from 0 to
        ' 8
        Call m.addColorScale(smoothColorScale, 52, 0, 52, 8)
    ElseIf chartIndex = 4 Then
        ' Add a 6-pixel thick high/low color scale at x = 53 (right of meter scale)
        Call m.addColorScale(highLowColorScale, 53, 6)
    Else
        ' Add a 6-pixel thick step color scale at x = 53 (right of meter scale)
        Call m.addColorScale(stepColorScale, 53, 6)
    End If

    ' Add a bar from 0 to value with glass effect and 4 pixel rounded corners
    Call m.addBar(0, value, barColor(chartIndex), cd.glassEffect(cd.NormalGlare, cd.Left), 4)

    ' Add a title using white (0xffffff) 8pt Arial Bold font with a border color background
    Call m.addTitle("Temp C", "arialbd.ttf", 8, &Hffffff).setBackground(borderColor(chartIndex))

    ' Add a bottom title using white (0xffffff) 8pt Arial Bold font with a border color background
    ' to display the value
    Call m.addTitle2(cd.Bottom, m.formatValue(value, "2"), "arialbd.ttf", 8, &Hffffff _
        ).setBackground(borderColor(chartIndex))

    ' Output the chart
    Set viewer.Picture = m.makePicture()

End Sub