ChartDirector 6.0 (ASP/COM/VB Edition)

Cone Chart




This example demonstrates using PyramidChart.setConeSize to specify using a cone instead of a pyramid to represent the data.

Source Code Listing

[Web Version (in ASP)] aspdemo\cone.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The data for the pyramid chart
data = Array(156, 123, 211, 179)

' The labels for the pyramid chart
labels = Array("Funds", "Bonds", "Stocks", "Cash")

' The semi-transparent colors for the pyramid layers
colors = Array(&H60000088, &H6066aaee, &H60ffbb00, &H60ee6622)

' Create a PyramidChart object of size 480 x 400 pixels
Set c = cd.PyramidChart(480, 400)

' Set the cone center at (280, 180), and width x height to 150 x 300 pixels
Call c.setConeSize(280, 180, 150, 300)

' Set the elevation to 15 degrees
Call c.setViewAngle(15)

' Set the pyramid data and labels
Call c.setData(data, labels)

' Set the layer colors to the given colors
Call c.setColors2(cd.DataColor, colors)

' Leave 1% gaps between layers
Call c.setLayerGap(0.01)

' Add labels at the left side of the pyramid layers using Arial Bold font. The labels will have 3
' lines showing the layer name, value and percentage.
Call c.setLeftLabel("{label}<*br*>US ${value}K<*br*>({percent}%)", "arialbd.ttf")

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite c.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\cone.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The data for the pyramid chart
    Dim data()
    data = Array(156, 123, 211, 179)

    ' The labels for the pyramid chart
    Dim labels()
    labels = Array("Funds", "Bonds", "Stocks", "Cash")

    ' The semi-transparent colors for the pyramid layers
    Dim colors()
    colors = Array(&H60000088, &H6066aaee, &H60ffbb00, &H60ee6622)

    ' Create a PyramidChart object of size 480 x 400 pixels
    Dim c As PyramidChart
    Set c = cd.PyramidChart(480, 400)

    ' Set the cone center at (280, 180), and width x height to 150 x 300 pixels
    Call c.setConeSize(280, 180, 150, 300)

    ' Set the elevation to 15 degrees
    Call c.setViewAngle(15)

    ' Set the pyramid data and labels
    Call c.setData(data, labels)

    ' Set the layer colors to the given colors
    Call c.setColors2(cd.DataColor, colors)

    ' Leave 1% gaps between layers
    Call c.setLayerGap(0.01)

    ' Add labels at the left side of the pyramid layers using Arial Bold font. The labels will have
    ' 3 lines showing the layer name, value and percentage.
    Call c.setLeftLabel("{label}<*br*>US ${value}K<*br*>({percent}%)", "arialbd.ttf")

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", _
        "title='{label}: US$ {value}K ({percent}%)'")

End Sub