ChartDirector 6.0 (ASP/COM/VB Edition)

Confidence Band




This example demonstrates adding confidence bands to a trend line. It also demonstrates how to display linear regression parameters on the chart.

In linear regression, the data points are assumed to be related by:

y = m * x + c + err

where m and c are constants, and err is a random variable. Linear regression estimates m, c and err based on available data.

As m and c are estimated values, the trend line y = m * x + c may be inaccurate. In ChartDirector, the uncertainties can be represented as a confidence band using TrendLayer.addConfidenceBand. For example, the 95% confidence band means there are 95% probability that the "real" trend line is in that band.

To predict a data point (infer y given x), we use y = m * x + c + err. As m, c and err are estimated values, the predicted data point may be inaccurate. In ChartDirector, the uncertainties can be represented as a prediction band using TrendLayer.addPredictionBand.

Note that the prediction band is always wider than the confidence band because of the extra uncertainties contributed by the err term.

In ChartDirector, the linear regression parameters slope, intercept, correlation coefficient and standard error can be obtained by using TrendLayer.getSlope, TrendLayer.getIntercept, TrendLayer.getCorrelation and TrendLayer.getStdError. (Please refer to appropriate statistics text books for explanation of these values.)

In this example, the linear regression parameters are formatted into a table using CDML, which is then added to the chart as custom text box using BaseChart.addText.

Source Code Listing

[Web Version (in ASP)] aspdemo\confidenceband.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The XY data of the first data series
dataX = Array(50, 55, 37, 24, 42, 49, 63, 72, 83, 59)
dataY = Array(3.6, 2.8, 2.5, 2.3, 3.8, 3.0, 3.8, 5.0, 6.0, 3.3)

' Create a XYChart object of size 450 x 420 pixels
Set c = cd.XYChart(450, 420)

' Set the plotarea at (55, 65) and of size 350 x 300 pixels, with white background and a light grey
' border (0xc0c0c0). Turn on both horizontal and vertical grid lines with light grey color
' (0xc0c0c0)
Call c.setPlotArea(55, 65, 350, 300, &Hffffff, -1, &Hc0c0c0, &Hc0c0c0, -1)

' Add a title to the chart using 18 point Times Bold Itatic font.
Call c.addTitle("Server Performance", "timesbi.ttf", 18)

' Add titles to the axes using 12pt Arial Bold Italic font
Call c.yAxis().setTitle("Response Time (sec)", "arialbi.ttf", 12)
Call c.xAxis().setTitle("Server Load (TPS)", "arialbi.ttf", 12)

' Set the axes line width to 3 pixels
Call c.yAxis().setWidth(3)
Call c.xAxis().setWidth(3)

' Add a scatter layer using (dataX, dataY)
Call c.addScatterLayer(dataX, dataY, "", cd.DiamondSymbol, 11, &H008000)

' Add a trend line layer for (dataX, dataY)
Set trendLayer = c.addTrendLayer2(dataX, dataY, &H008000)

' Set the line width to 3 pixels
Call trendLayer.setLineWidth(3)

' Add a 95% confidence band for the line
Call trendLayer.addConfidenceBand(0.95, &H806666ff)

' Add a 95% confidence band (prediction band) for the points
Call trendLayer.addPredictionBand(0.95, &H8066ff66)

' Add a legend box at (50, 30) (top of the chart) with horizontal layout. Use 10pt Arial Bold Italic
' font. Set the background and border color to Transparent.
Set legendBox = c.addLegend(50, 30, False, "arialbi.ttf", 10)
Call legendBox.setBackground(cd.Transparent)

' Add entries to the legend box
Call legendBox.addKey("95% Line Confidence", &H806666ff)
Call legendBox.addKey("95% Point Confidence", &H8066ff66)

' Display the trend line parameters as a text table formatted using CDML
Set textbox = c.addText(56, 65, _
    "<*block*>Slope<*br*>Intercept<*br*>Correlation<*br*>Std Error<*/*>   <*block*>" & _
    FormatNumber(trendLayer.getSlope(), 4) & " sec/tps<*br*>" & FormatNumber( _
    trendLayer.getIntercept(), 4) & " sec<*br*>" & FormatNumber(trendLayer.getCorrelation(), 4) & _
    "<*br*>" & FormatNumber(trendLayer.getStdError(), 4) & " sec<*/*>", "arialbd.ttf", 8)

' Set the background of the text box to light grey, with a black border, and 1 pixel 3D border
Call textbox.setBackground(&Hc0c0c0, 0, 1)

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite c.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\confidenceband.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The XY data of the first data series
    Dim dataX()
    dataX = Array(50, 55, 37, 24, 42, 49, 63, 72, 83, 59)
    Dim dataY()
    dataY = Array(3.6, 2.8, 2.5, 2.3, 3.8, 3.0, 3.8, 5.0, 6.0, 3.3)

    ' Create a XYChart object of size 450 x 420 pixels
    Dim c As XYChart
    Set c = cd.XYChart(450, 420)

    ' Set the plotarea at (55, 65) and of size 350 x 300 pixels, with white background and a light
    ' grey border (0xc0c0c0). Turn on both horizontal and vertical grid lines with light grey color
    ' (0xc0c0c0)
    Call c.setPlotArea(55, 65, 350, 300, &Hffffff, -1, &Hc0c0c0, &Hc0c0c0, -1)

    ' Add a title to the chart using 18 point Times Bold Itatic font.
    Call c.addTitle("Server Performance", "timesbi.ttf", 18)

    ' Add titles to the axes using 12pt Arial Bold Italic font
    Call c.yAxis().setTitle("Response Time (sec)", "arialbi.ttf", 12)
    Call c.xAxis().setTitle("Server Load (TPS)", "arialbi.ttf", 12)

    ' Set the axes line width to 3 pixels
    Call c.yAxis().setWidth(3)
    Call c.xAxis().setWidth(3)

    ' Add a scatter layer using (dataX, dataY)
    Dim scatterLayer As ScatterLayer
    Set scatterLayer = c.addScatterLayer(dataX, dataY, "", cd.DiamondSymbol, 11, &H008000)

    ' tool tip for scatter layer
    Call scatterLayer.setHTMLImageMap("", "", "title='Response time at {x} TPS: {value} sec'")

    ' Add a trend line layer for (dataX, dataY)
    Dim trendLayer As TrendLayer
    Set trendLayer = c.addTrendLayer2(dataX, dataY, &H008000)

    ' Set the line width to 3 pixels
    Call trendLayer.setLineWidth(3)

    ' Add a 95% confidence band for the line
    Call trendLayer.addConfidenceBand(0.95, &H806666ff)

    ' Add a 95% confidence band (prediction band) for the points
    Call trendLayer.addPredictionBand(0.95, &H8066ff66)

    ' tool tip for trend layer
    Call trendLayer.setHTMLImageMap("", "", _
        "title='Slope = {slope|4} sec/TPS; Intercept = {intercept|4} sec'")

    ' Add a legend box at (50, 30) (top of the chart) with horizontal layout. Use 10pt Arial Bold
    ' Italic font. Set the background and border color to Transparent.
    Dim legendBox As LegendBox
    Set legendBox = c.addLegend(50, 30, False, "arialbi.ttf", 10)
    Call legendBox.setBackground(cd.Transparent)

    ' Add entries to the legend box
    Call legendBox.addKey("95% Line Confidence", &H806666ff)
    Call legendBox.addKey("95% Point Confidence", &H8066ff66)

    ' Display the trend line parameters as a text table formatted using CDML
    Dim textbox As ChartDirector.TextBox
    Set textbox = c.addText(56, 65, _
        "<*block*>Slope<*br*>Intercept<*br*>Correlation<*br*>Std Error<*/*>   <*block*>" & _
        FormatNumber(trendLayer.getSlope(), 4) & " sec/tps<*br*>" & FormatNumber( _
        trendLayer.getIntercept(), 4) & " sec<*br*>" & FormatNumber(trendLayer.getCorrelation(), 4 _
        ) & "<*br*>" & FormatNumber(trendLayer.getStdError(), 4) & " sec<*/*>", "arialbd.ttf", 8)

    ' Set the background of the text box to light grey, with a black border, and 1 pixel 3D border
    Call textbox.setBackground(&Hc0c0c0, 0, 1)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    ' include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable")

End Sub