ChartDirector 6.0 (ASP/COM/VB Edition)

Database Clickable Charts




In this section, we will present an example that employs both database and image maps.

This example displays a bar chart that shows the revenue for the last 10 years. When the user clicks on a bar, it will "drill down" to another bar chart showing the monthly revenue for the year represented by the bar clicked. All data come from a database.

The code that creates the clickable bar chart for the last 10 years are as follows.

[Web Version (in ASP)] aspdemo\dbdemo3.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' SQL statement to get the revenue for the 12 years from 1990 to 2001
SQL = _
    "Select Sum(Software + Hardware + Services), Year(TimeStamp) From revenue Where " & _
    "Year(TimeStamp) >= 1990 And Year(TimeStamp) <= 2001 Group By Year(TimeStamp) Order By " & _
    "Year(TimeStamp)"

'
' Connect to database and read the query result into arrays
'
Set rs = CreateObject("ADODB.RecordSet")
Call rs.Open(SQL, "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & _
    Server.MapPath("sample.mdb"))
Set dbTable = cd.DBTable(rs)
rs.Close()

revenue = dbTable.getCol(0)
timestamp = dbTable.getCol(1)

'
' Now we have read data into arrays, we can draw the chart using ChartDirector
'

' Create a XYChart object of size 600 x 360 pixels
Set c = cd.XYChart(600, 360)

' Set the plotarea at (60, 40) and of size 480 x 280 pixels. Use a vertical gradient color from
' light blue (eeeeff) to deep blue (0000cc) as background. Set border and grid lines to white
' (ffffff).
Call c.setPlotArea(60, 40, 480, 280, c.linearGradientColor(60, 40, 60, 280, &Heeeeff, &H0000cc), _
    -1, &Hffffff, &Hffffff)

' Add a title to the chart using 18pt Times Bold Italic font
Call c.addTitle("Annual Revenue for Star Tech", "timesbi.ttf", 18)

' Add a multi-color bar chart layer using the supplied data
Set layer = c.addBarLayer3(revenue)

' Use glass lighting effect with light direction from the left
Call layer.setBorderColor(cd.Transparent, cd.glassEffect(cd.NormalGlare, cd.Left))

' Set the x axis labels
Call c.xAxis().setLabels(timestamp)

' Set y-axis tick density to 30 pixels. ChartDirector auto-scaling will use this as the guideline
' when putting ticks on the y-axis.
Call c.yAxis().setTickDensity(30)

' Synchronize the left and right y-axes
Call c.syncYAxis()

' Set the y axes titles with 10pt Arial Bold font
Call c.yAxis().setTitle("USD (Millions)", "arialbd.ttf", 10)
Call c.yAxis2().setTitle("USD (Millions)", "arialbd.ttf", 10)

' Set all axes to transparent
Call c.xAxis().setColors(cd.Transparent)
Call c.yAxis().setColors(cd.Transparent)
Call c.yAxis2().setColors(cd.Transparent)

' Set the label styles of all axes to 8pt Arial Bold font
Call c.xAxis().setLabelStyle("arialbd.ttf", 8)
Call c.yAxis().setLabelStyle("arialbd.ttf", 8)
Call c.yAxis2().setLabelStyle("arialbd.ttf", 8)

' Create the image
chart1URL = c.makeSession(Session, "chart1")

' Create an image map for the chart
imageMap = c.getHTMLImageMap("dbdemo3a.asp", "", "title='{xLabel}: US$ {value|0}M'")
%>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Database Clickable Charts
</div>
<hr style="border:solid 1px #000080" />
<div style="font-size:10pt; font-family:verdana; width:600px; margin-bottom:20px">
    The example demonstrates creating a clickable chart using data from a database.
    Click on a bar below to "drill down" onto a particular year.
<br /><br />
<a href='viewsource.asp?file=<%=Request("SCRIPT_NAME")%>'>
    View source code
</a>
</div>

<img src="getchart.asp?<%=chart1URL%>" border="0" usemap="#map1">
<map name="map1">
<%=imageMap%>
</map>

</body>
</html>

The above code first performs a database query and read the data into arrays. It then uses the data to create a bar chart. The chart is saved in a session variable using BaseChart.makeSession. An <IMG> tag is used to retrieve the chart with "getchart.asp?<%=chart1URL%>" as the URL. "getchart.asp" is a simple utility that comes with ChartDirector for retrieving images from session variables. The image map for the chart is created using BaseChart.getHTMLImageMap with "dbdemo3a.asp" as the handler.

NOTE: This sample script uses "getchart.asp" and assumes it is in the same directory as the script. When developing your own script using this sample script as a template, please ensure you copy "getchart.asp" to the same directory as your script. If you put "getchart.asp" in other directory, please adjust the paths in your script accordingly.

When the user clicks on the bar chart, "dbdemo3a.asp" will be invoked with a number of HTTP query parameters to indicate which bar the user has clicked. In particular, the xLabel parameter will contain the x-axis label for the bar clicked. With this parameter, "dbdemo3a.asp" can determine which year the user has clicked. It can then query the database for the data in that year, and produces the bar chart for that year.

In this example, "dbdemo3a.asp" will produce another clickable chart using "xystub.asp" as the handler.

[Web Version (in ASP)] aspdemo\dbdemo3a.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

'
' Displays the monthly revenue for the selected year. The selected year should be passed in as a
' query parameter called "xLabel"
'
selectedYear = Request("xLabel")
if selectedYear = "" Then selectedYear = 2001

' SQL statement to get the monthly revenues for the selected year.
SQL = "Select Software, Hardware, Services From revenue Where Year(TimeStamp) = " & selectedYear & _
    " Order By TimeStamp"

'
' Connect to database and read the query result into arrays
'

Set rs = CreateObject("ADODB.RecordSet")
Call rs.Open(SQL, "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & _
    Server.MapPath("sample.mdb"))
Set dbTable = cd.DBTable(rs)
rs.Close()

software = dbTable.getCol(0)
hardware = dbTable.getCol(1)
services = dbTable.getCol(2)

'
' Now we have read data into arrays, we can draw the chart using ChartDirector
'

' Create a XYChart object of size 600 x 360 pixels
Set c = cd.XYChart(600, 360)

' Set the plotarea at (60, 50) and of size 480 x 270 pixels. Use a vertical gradient color from
' light blue (eeeeff) to deep blue (0000cc) as background. Set border and grid lines to white
' (ffffff).
Call c.setPlotArea(60, 50, 480, 270, c.linearGradientColor(60, 50, 60, 270, &Heeeeff, &H0000cc), _
    -1, &Hffffff, &Hffffff)

' Add a title to the chart using 15pt Times Bold Italic font
Call c.addTitle("Global Revenue for Year " & selectedYear, "timesbi.ttf", 18)

' Add a legend box at (60, 25) (top of the plotarea) with 9pt Arial Bold font
Call c.addLegend(60, 25, False, "arialbd.ttf", 9).setBackground(cd.Transparent)

' Add a line chart layer using the supplied data
Set layer = c.addLineLayer2()
Call layer.addDataSet(software, &Hffaa00, "Software").setDataSymbol(cd.CircleShape, 9)
Call layer.addDataSet(hardware, &H00ff00, "Hardware").setDataSymbol(cd.DiamondShape, 11)
Call layer.addDataSet(services, &Hff0000, "Services").setDataSymbol(cd.Cross2Shape(), 11)

' Set the line width to 3 pixels
Call layer.setLineWidth(3)

' Set the x axis labels. In this example, the labels must be Jan - Dec.
labels = Array("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sept", "Oct", "Nov", "Dec")
Call c.xAxis().setLabels(labels)

' Set y-axis tick density to 30 pixels. ChartDirector auto-scaling will use this as the guideline
' when putting ticks on the y-axis.
Call c.yAxis().setTickDensity(30)

' Synchronize the left and right y-axes
Call c.syncYAxis()

' Set the y axes titles with 10pt Arial Bold font
Call c.yAxis().setTitle("USD (Millions)", "arialbd.ttf", 10)
Call c.yAxis2().setTitle("USD (Millions)", "arialbd.ttf", 10)

' Set all axes to transparent
Call c.xAxis().setColors(cd.Transparent)
Call c.yAxis().setColors(cd.Transparent)
Call c.yAxis2().setColors(cd.Transparent)

' Set the label styles of all axes to 8pt Arial Bold font
Call c.xAxis().setLabelStyle("arialbd.ttf", 8)
Call c.yAxis().setLabelStyle("arialbd.ttf", 8)
Call c.yAxis2().setLabelStyle("arialbd.ttf", 8)

' Create the image and save it in a temporary location
chart1URL = c.makeSession(Session, "chart1")

' Create an image map for the chart
imageMap = c.getHTMLImageMap("xystub.asp", "", "title='{dataSetName} @ {xLabel} = USD {value|0}M'")
%>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Database Clickable Charts
</div>
<hr style="border:solid 1px #000080" />
<div style="font-size:10pt; font-family:verdana; width:600px; margin-bottom:20px">
    You have click the bar for the year <%=selectedYear%>.
    Below is the "drill-down" chart showing the monthly details.
<br /><br />
<a href='viewsource.asp?file=<%=Request("SCRIPT_NAME")%>'>
    View source code
</a>
</div>

<img src="getchart.asp?<%=chart1URL%>" border="0" usemap="#map1">
<map name="map1">
<%=imageMap%>
</map>

</body>
</html>

For demo purpose, "xystub.asp" simply displays information on what is clicked. It's source code is as follows.

[Web Version (in ASP)] aspdemo\xystub.asp
<%@ language="vbscript" %>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Simple Clickable XY Chart Handler
</div>
<hr style="border:solid 1px #000080" />
<div style="font-size:10pt; font-family:verdana; margin-bottom:20px">
    <a href="viewsource.asp?file=<%=Request("SCRIPT_NAME")%>">View Source Code</a>
</div>
<div style="font-size:10pt; font-family:verdana;">
<b>You have clicked on the following chart element :</b><br />
<ul>
    <li>Data Set : <%=Request("dataSetName")%></li>
    <li>X Position : <%=Request("x")%></li>
    <li>X Label : <%=Request("xLabel")%></li>
    <li>Data Value : <%=Request("value")%></li>
</ul>
</div>
</body>
</html>