ChartDirector 6.0 (ASP/COM/VB Edition)

Line with Error Symbols




This example demonstrates combining a line layer with a box-whisker layer to draw a line with error symbols.

The blue line and the yellow diamond symbols are from the line layer, created using XYChart.addLineLayer2, Layer.addDataSet, and DataSet.setDataSymbol.

The error symbols come from the box-whisker layer, created using XYChart.addBoxWhiskerLayer. In this example, the "box" parts of the box- whisker symbols are disabled by setting the data for the box and median to empty arrays. As a result, only the "whisker" parts of the box-whisker symbols are visible and they become the error symbols.

The maximum and minimum marks in this example is computed by adding/subtracting the error value to/from the data value using a ChartDirector utility class ArrayMath.

Source Code Listing

[Web Version (in ASP)] aspdemo\errline.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The data with error information
data = Array(42, 49, 33, 38, 51, 46, 29, 41, 44, 57, 59, 52, 37, 34, 51, 56, 56, 60, 70, 76, 63, _
    67, 75, 64, 51)
errData = Array(5, 6, 5.1, 6.5, 6.6, 8, 5.4, 5.1, 4.6, 5.0, 5.2, 6.0, 4.9, 5.6, 4.8, 6.2, 7.4, _
    7.1, 6.0, 6.6, 7.1, 5.3, 5.5, 7.9, 6.1)

' The labels for the chart
labels = Array("0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "10", "11", "12", "13", "14", _
    "15", "16", "17", "18", "19", "20", "21", "22", "23", "24")

' Create a XYChart object of size 600 x 300 pixels, with a light grey (eeeeee) background, black
' border, 1 pixel 3D border effect and rounded corners.
Set c = cd.XYChart(600, 300, &Heeeeee, &H000000, 1)
Call c.setRoundedFrame()

' Set default directory for loading images from current script directory
Call c.setSearchPath(Server.MapPath("."))

' Set the plotarea at (55, 55) and of size 520 x 195 pixels, with white (ffffff) background. Set
' horizontal and vertical grid lines to grey (cccccc).
Call c.setPlotArea(55, 55, 520, 195, &Hffffff, -1, -1, &Hcccccc, &Hcccccc)

' Add a title box to the chart using 15pt Times Bold Italic font. The title is in CDML and includes
' embedded images for highlight. The text is on a light grey (dddddd) background, with glass
' lighting effect.
Call c.addTitle( _
    "<*block,valign=absmiddle*><*img=star.png*><*img=star.png*> Molecular Temperature Control " & _
    "<*img=star.png*><*img=star.png*><*/*>", "timesbi.ttf", 15).setBackground(&Hdddddd, 0, _
    cd.glassEffect())

' Add a title to the y axis
Call c.yAxis().setTitle("Temperature")

' Add a title to the x axis using CMDL
Call c.xAxis().setTitle("<*block,valign=absmiddle*><*img=clock.png*>  Elapsed Time (hour)<*/*>")

' Set the labels on the x axis.
Call c.xAxis().setLabels(labels)

' Display 1 out of 3 labels on the x-axis. Show minor ticks for remaining labels.
Call c.xAxis().setLabelStep(3, 1)

' Set the axes width to 2 pixels
Call c.xAxis().setWidth(2)
Call c.yAxis().setWidth(2)

' Add a line layer to the chart
Set lineLayer = c.addLineLayer2()

' Add a blue (0xff) data set to the line layer, with yellow (0xffff80) diamond symbols
Call lineLayer.addDataSet(data, &H0000ff).setDataSymbol(cd.DiamondSymbol, 12, &Hffff80)

' Set the line width to 2 pixels
Call lineLayer.setLineWidth(2)

' Add a box whisker layer to the chart. Use the upper and lower mark of the box whisker layer to act
' as error zones. The upper and lower marks are computed using the ArrayMath object.
Set errLayer = c.addBoxWhiskerLayer(Empty, Empty, cd.ArrayMath(data).add(errData).result(), _
    cd.ArrayMath(data).subtract(errData).result(), data, cd.Transparent, &Hbb6633)

' Set the line width to 2 pixels
Call errLayer.setLineWidth(2)

' Set the error zone to occupy half the space between the symbols
Call errLayer.setDataGap(0.5)

' Add a custom CDML text at the bottom right of the plot area as the logo
Call c.addText(575, 247, _
    "<*block,valign=absmiddle*><*img=small_molecule.png*> <*block*>" & _
    "<*font=timesbi.ttf,size=10,color=804040*>Molecular<*br*>Engineering<*/*>").setAlignment( _
    cd.BottomRight)

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite c.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\errline.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The data with error information
    Dim data()
    data = Array(42, 49, 33, 38, 51, 46, 29, 41, 44, 57, 59, 52, 37, 34, 51, 56, 56, 60, 70, 76, _
        63, 67, 75, 64, 51)
    Dim errData()
    errData = Array(5, 6, 5.1, 6.5, 6.6, 8, 5.4, 5.1, 4.6, 5.0, 5.2, 6.0, 4.9, 5.6, 4.8, 6.2, 7.4, _
        7.1, 6.0, 6.6, 7.1, 5.3, 5.5, 7.9, 6.1)

    ' The labels for the chart
    Dim labels()
    labels = Array("0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "10", "11", "12", "13", "14", _
        "15", "16", "17", "18", "19", "20", "21", "22", "23", "24")

    ' Create a XYChart object of size 600 x 300 pixels, with a light grey (eeeeee) background, black
    ' border, 1 pixel 3D border effect and rounded corners.
    Dim c As XYChart
    Set c = cd.XYChart(600, 300, &Heeeeee, &H000000, 1)
    Call c.setRoundedFrame()

    ' Set the plotarea at (55, 55) and of size 520 x 195 pixels, with white (ffffff) background. Set
    ' horizontal and vertical grid lines to grey (cccccc).
    Call c.setPlotArea(55, 55, 520, 195, &Hffffff, -1, -1, &Hcccccc, &Hcccccc)

    ' Add a title box to the chart using 15pt Times Bold Italic font. The title is in CDML and
    ' includes embedded images for highlight. The text is on a light grey (dddddd) background, with
    ' glass lighting effect.
    Call c.addTitle( _
        "<*block,valign=absmiddle*><*img=star.png*><*img=star.png*> Molecular Temperature " & _
        "Control <*img=star.png*><*img=star.png*><*/*>", "timesbi.ttf", 15).setBackground( _
        &Hdddddd, 0, cd.glassEffect())

    ' Add a title to the y axis
    Call c.yAxis().setTitle("Temperature")

    ' Add a title to the x axis using CMDL
    Call c.xAxis().setTitle( _
        "<*block,valign=absmiddle*><*img=clock.png*>  Elapsed Time (hour)<*/*>")

    ' Set the labels on the x axis.
    Call c.xAxis().setLabels(labels)

    ' Display 1 out of 3 labels on the x-axis. Show minor ticks for remaining labels.
    Call c.xAxis().setLabelStep(3, 1)

    ' Set the axes width to 2 pixels
    Call c.xAxis().setWidth(2)
    Call c.yAxis().setWidth(2)

    ' Add a line layer to the chart
    Dim lineLayer As LineLayer
    Set lineLayer = c.addLineLayer2()

    ' Add a blue (0xff) data set to the line layer, with yellow (0xffff80) diamond symbols
    Call lineLayer.addDataSet(data, &H0000ff).setDataSymbol(cd.DiamondSymbol, 12, &Hffff80)

    ' Set the line width to 2 pixels
    Call lineLayer.setLineWidth(2)

    ' Add a box whisker layer to the chart. Use the upper and lower mark of the box whisker layer to
    ' act as error zones. The upper and lower marks are computed using the ArrayMath object.
    Dim errLayer As BoxWhiskerLayer
    Set errLayer = c.addBoxWhiskerLayer(Empty, Empty, cd.ArrayMath(data).add(errData).result(), _
        cd.ArrayMath(data).subtract(errData).result(), data, cd.Transparent, &Hbb6633)

    ' Set the line width to 2 pixels
    Call errLayer.setLineWidth(2)

    ' Set the error zone to occupy half the space between the symbols
    Call errLayer.setDataGap(0.5)

    ' Add a custom CDML text at the bottom right of the plot area as the logo
    Call c.addText(575, 247, _
        "<*block,valign=absmiddle*><*img=small_molecule.png*> <*block*>" & _
        "<*font=timesbi.ttf,size=10,color=804040*>Molecular<*br*>Engineering<*/*>").setAlignment( _
        cd.BottomRight)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    ' Include tool tip for the chart. We only need to show the tool tip for the box whisker layer.
    viewer.ImageMap = errLayer.getHTMLImageMap("clickable", "", _
        "title='Temperature at hour {xLabel}: {med} +/- {={med}-{min}} C'")

End Sub