ChartDirector 6.0 (ASP/COM/VB Edition)

Icon Pie Chart (1)




This example demonstrates using CDML and Parameter Substitution and Formatting to include icons in sector labels. It also demonstrates gradient background color, glass shading effect for the title and rounded corners for the chart frame.

Source Code Listing

[Web Version (in ASP)] aspdemo\iconpie.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The data for the pie chart
data = Array(72, 18, 15, 12)

' The depths for the sectors
depths = Array(30, 20, 10, 10)

' The labels for the pie chart
labels = Array("Sunny", "Cloudy", "Rainy", "Snowy")

' The icons for the sectors
icons = Array("sun.png", "cloud.png", "rain.png", "snowy.png")

' Create a PieChart object of size 400 x 310 pixels, with a blue (CCCCFF) vertical metal gradient
' background, black border, 1 pixel 3D border effect and rounded corners
Set c = cd.PieChart(400, 310, cd.metalColor(&Hccccff, 0), &H000000, 1)
Call c.setRoundedFrame()

' Set default directory for loading images from current script directory
Call c.setSearchPath(Server.MapPath("."))

' Set the center of the pie at (200, 180) and the radius to 100 pixels
Call c.setPieSize(200, 180, 100)

' Add a title box using 15pt Times Bold Italic font, on a blue (CCCCFF) background with glass effect
Call c.addTitle("Weather Profile in Wonderland", "timesbi.ttf", 15).setBackground(&Hccccff, _
    &H000000, cd.glassEffect())

' Set the pie data and the pie labels
Call c.setData(data, labels)

' Add icons to the chart as a custom field
Call c.addExtraField(icons)

' Configure the sector labels using CDML to include the icon images
Call c.setLabelFormat( _
    "<*block,valign=absmiddle*><*img={field0}*> <*block*>{label}<*br*>{percent}%<*/*><*/*>")

' Draw the pie in 3D with variable 3D depths
Call c.set3D2(depths)

' Set the start angle to 225 degrees may improve layout when the depths of the sector are sorted in
' descending order, because it ensures the tallest sector is at the back.
Call c.setStartAngle(225)

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite c.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\iconpie.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The data for the pie chart
    Dim data()
    data = Array(72, 18, 15, 12)

    ' The depths for the sectors
    Dim depths()
    depths = Array(30, 20, 10, 10)

    ' The labels for the pie chart
    Dim labels()
    labels = Array("Sunny", "Cloudy", "Rainy", "Snowy")

    ' The icons for the sectors
    Dim icons()
    icons = Array("sun.png", "cloud.png", "rain.png", "snowy.png")

    ' Create a PieChart object of size 400 x 310 pixels, with a blue (CCCCFF) vertical metal
    ' gradient background, black border, 1 pixel 3D border effect and rounded corners
    Dim c As PieChart
    Set c = cd.PieChart(400, 310, cd.metalColor(&Hccccff, 0), &H000000, 1)
    Call c.setRoundedFrame()

    ' Set the center of the pie at (200, 180) and the radius to 100 pixels
    Call c.setPieSize(200, 180, 100)

    ' Add a title box using 15pt Times Bold Italic font, on a blue (CCCCFF) background with glass
    ' effect
    Call c.addTitle("Weather Profile in Wonderland", "timesbi.ttf", 15).setBackground(&Hccccff, _
        &H000000, cd.glassEffect())

    ' Set the pie data and the pie labels
    Call c.setData(data, labels)

    ' Add icons to the chart as a custom field
    Call c.addExtraField(icons)

    ' Configure the sector labels using CDML to include the icon images
    Call c.setLabelFormat( _
        "<*block,valign=absmiddle*><*img={field0}*> <*block*>{label}<*br*>{percent}%<*/*><*/*>")

    ' Draw the pie in 3D with variable 3D depths
    Call c.set3D2(depths)

    ' Set the start angle to 225 degrees may improve layout when the depths of the sector are sorted
    ' in descending order, because it ensures the tallest sector is at the back.
    Call c.setStartAngle(225)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", _
        "title='{label}: {value} days ({percent}%)'")

End Sub