ChartDirector 6.0 (ASP/COM/VB Edition)

Multi-Layer Gantt Chart




This example demonstrates a gantt chart containing two layers for the planned and actual dates.

The two layers are created using XYChart.addBoxWhiskerLayer. The bar width of the top layer is set using BaseBoxLayer.setDataWidth to a narrow width so that it will not block the bottom layer.

In this example, the color of the top layer is a pattern color created using an 4 x 4 in-memory pattern with BaseChart.patternColor.

Source Code Listing

[Web Version (in ASP)] aspdemo\layergantt.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' the names of the tasks
labels = Array("Market Research", "Define Specifications", "Overall Archiecture", _
    "Project Planning", "Detail Design", "Software Development", "Test Plan", "Testing and QA", _
    "User Documentation")

' the planned start dates and end dates for the tasks
startDate = Array(DateSerial(2004, 8, 16), DateSerial(2004, 8, 30), DateSerial(2004, 9, 13), _
    DateSerial(2004, 9, 20), DateSerial(2004, 9, 27), DateSerial(2004, 10, 4), DateSerial(2004, _
    10, 25), DateSerial(2004, 11, 1), DateSerial(2004, 11, 8))
endDate = Array(DateSerial(2004, 8, 30), DateSerial(2004, 9, 13), DateSerial(2004, 9, 27), _
    DateSerial(2004, 10, 4), DateSerial(2004, 10, 11), DateSerial(2004, 11, 8), DateSerial(2004, _
    11, 8), DateSerial(2004, 11, 22), DateSerial(2004, 11, 22))

' the actual start dates and end dates for the tasks up to now
actualStartDate = Array(DateSerial(2004, 8, 16), DateSerial(2004, 8, 27), DateSerial(2004, 9, 9), _
    DateSerial(2004, 9, 18), DateSerial(2004, 9, 22))
actualEndDate = Array(DateSerial(2004, 8, 27), DateSerial(2004, 9, 9), DateSerial(2004, 9, 27), _
    DateSerial(2004, 10, 2), DateSerial(2004, 10, 8))

' Create a XYChart object of size 620 x 280 pixels. Set background color to light green (ccffcc)
' with 1 pixel 3D border effect.
Set c = cd.XYChart(620, 280, &Hccffcc, &H000000, 1)

' Add a title to the chart using 15 points Times Bold Itatic font, with white (ffffff) text on a
' dark green (0x6000) background
Call c.addTitle("Multi-Layer Gantt Chart Demo", "timesbi.ttf", 15, &Hffffff).setBackground( _
    &H006000)

' Set the plotarea at (140, 55) and of size 460 x 200 pixels. Use alternative white/grey background.
' Enable both horizontal and vertical grids by setting their colors to grey (c0c0c0). Set vertical
' major grid (represents month boundaries) 2 pixels in width
Call c.setPlotArea(140, 55, 460, 200, &Hffffff, &Heeeeee, cd.LineColor, &Hc0c0c0, &Hc0c0c0 _
    ).setGridWidth(2, 1, 1, 1)

' swap the x and y axes to create a horziontal box-whisker chart
Call c.swapXY()

' Set the y-axis scale to be date scale from Aug 16, 2004 to Nov 22, 2004, with ticks every 7 days
' (1 week)
Call c.yAxis().setDateScale(DateSerial(2004, 8, 16), DateSerial(2004, 11, 22), 86400 * 7)

' Add a red (ff0000) dash line to represent the current day
Call c.yAxis().addMark(DateSerial(2004, 10, 8), c.dashLineColor(&Hff0000, cd.DashLine))

' Set multi-style axis label formatting. Month labels are in Arial Bold font in "mmm d" format.
' Weekly labels just show the day of month and use minor tick (by using '-' as first character of
' format string).
Call c.yAxis().setMultiFormat(cd.StartOfMonthFilter(), "<*font=arialbd.ttf*>{value|mmm d}", _
    cd.StartOfDayFilter(), "-{value|d}")

' Set the y-axis to shown on the top (right + swapXY = top)
Call c.setYAxisOnRight()

' Set the labels on the x axis
Call c.xAxis().setLabels(labels)

' Reverse the x-axis scale so that it points downwards.
Call c.xAxis().setReverse()

' Set the horizontal ticks and grid lines to be between the bars
Call c.xAxis().setTickOffset(0.5)

' Use blue (0000aa) as the color for the planned schedule
plannedColor = &H0000aa

' Use a red hash pattern as the color for the actual dates. The pattern is created as a 4 x 4 bitmap
' defined in memory as an array of colors.
actualColor = c.patternColor(Array(&Hffffff, &Hffffff, &Hffffff, &Hff0000, &Hffffff, &Hffffff, _
    &Hff0000, &Hffffff, &Hffffff, &Hff0000, &Hffffff, &Hffffff, &Hff0000, &Hffffff, &Hffffff, _
    &Hffffff), 4)

' Add a box whisker layer to represent the actual dates. We add the actual dates layer first, so it
' will be the top layer.
Set actualLayer = c.addBoxLayer(actualStartDate, actualEndDate, actualColor, "Actual")

' Set the bar height to 8 pixels so they will not block the bottom bar
Call actualLayer.setDataWidth(8)

' Add a box-whisker layer to represent the planned schedule date
Call c.addBoxLayer(startDate, endDate, plannedColor, "Planned").setBorderColor(cd.SameAsMainColor)

' Add a legend box on the top right corner (595, 60) of the plot area with 8 pt Arial Bold font. Use
' a semi-transparent grey (80808080) background.
Set b = c.addLegend(595, 60, False, "arialbd.ttf", 8)
Call b.setAlignment(cd.TopRight)
Call b.setBackground(&H80808080, -1, 2)

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite c.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\layergantt.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' the names of the tasks
    Dim labels()
    labels = Array("Market Research", "Define Specifications", "Overall Archiecture", _
        "Project Planning", "Detail Design", "Software Development", "Test Plan", _
        "Testing and QA", "User Documentation")

    ' the planned start dates and end dates for the tasks
    Dim startDate()
    startDate = Array(DateSerial(2004, 8, 16), DateSerial(2004, 8, 30), DateSerial(2004, 9, 13), _
        DateSerial(2004, 9, 20), DateSerial(2004, 9, 27), DateSerial(2004, 10, 4), DateSerial( _
        2004, 10, 25), DateSerial(2004, 11, 1), DateSerial(2004, 11, 8))
    Dim endDate()
    endDate = Array(DateSerial(2004, 8, 30), DateSerial(2004, 9, 13), DateSerial(2004, 9, 27), _
        DateSerial(2004, 10, 4), DateSerial(2004, 10, 11), DateSerial(2004, 11, 8), DateSerial( _
        2004, 11, 8), DateSerial(2004, 11, 22), DateSerial(2004, 11, 22))

    ' the actual start dates and end dates for the tasks up to now
    Dim actualStartDate()
    actualStartDate = Array(DateSerial(2004, 8, 16), DateSerial(2004, 8, 27), DateSerial(2004, 9, _
        9), DateSerial(2004, 9, 18), DateSerial(2004, 9, 22))
    Dim actualEndDate()
    actualEndDate = Array(DateSerial(2004, 8, 27), DateSerial(2004, 9, 9), DateSerial(2004, 9, 27 _
        ), DateSerial(2004, 10, 2), DateSerial(2004, 10, 8))

    ' Create a XYChart object of size 620 x 280 pixels. Set background color to light green (ccffcc)
    ' with 1 pixel 3D border effect.
    Dim c As XYChart
    Set c = cd.XYChart(620, 280, &Hccffcc, &H000000, 1)

    ' Add a title to the chart using 15 points Times Bold Itatic font, with white (ffffff) text on a
    ' dark green (0x6000) background
    Call c.addTitle("Multi-Layer Gantt Chart Demo", "timesbi.ttf", 15, &Hffffff).setBackground( _
        &H006000)

    ' Set the plotarea at (140, 55) and of size 460 x 200 pixels. Use alternative white/grey
    ' background. Enable both horizontal and vertical grids by setting their colors to grey
    ' (c0c0c0). Set vertical major grid (represents month boundaries) 2 pixels in width
    Call c.setPlotArea(140, 55, 460, 200, &Hffffff, &Heeeeee, cd.LineColor, &Hc0c0c0, &Hc0c0c0 _
        ).setGridWidth(2, 1, 1, 1)

    ' swap the x and y axes to create a horziontal box-whisker chart
    Call c.swapXY()

    ' Set the y-axis scale to be date scale from Aug 16, 2004 to Nov 22, 2004, with ticks every 7
    ' days (1 week)
    Call c.yAxis().setDateScale(DateSerial(2004, 8, 16), DateSerial(2004, 11, 22), 86400 * 7)

    ' Add a red (ff0000) dash line to represent the current day
    Call c.yAxis().addMark(DateSerial(2004, 10, 8), c.dashLineColor(&Hff0000, cd.DashLine))

    ' Set multi-style axis label formatting. Month labels are in Arial Bold font in "mmm d" format.
    ' Weekly labels just show the day of month and use minor tick (by using '-' as first character
    ' of format string).
    Call c.yAxis().setMultiFormat(cd.StartOfMonthFilter(), "<*font=arialbd.ttf*>{value|mmm d}", _
        cd.StartOfDayFilter(), "-{value|d}")

    ' Set the y-axis to shown on the top (right + swapXY = top)
    Call c.setYAxisOnRight()

    ' Set the labels on the x axis
    Call c.xAxis().setLabels(labels)

    ' Reverse the x-axis scale so that it points downwards.
    Call c.xAxis().setReverse()

    ' Set the horizontal ticks and grid lines to be between the bars
    Call c.xAxis().setTickOffset(0.5)

    ' Use blue (0000aa) as the color for the planned schedule
    Dim plannedColor As Long
    plannedColor = &H0000aa

    ' Use a red hash pattern as the color for the actual dates. The pattern is created as a 4 x 4
    ' bitmap defined in memory as an array of colors.
    Dim actualColor As Long
    actualColor = c.patternColor(Array(&Hffffff, &Hffffff, &Hffffff, &Hff0000, &Hffffff, &Hffffff, _
        &Hff0000, &Hffffff, &Hffffff, &Hff0000, &Hffffff, &Hffffff, &Hff0000, &Hffffff, &Hffffff, _
        &Hffffff), 4)

    ' Add a box whisker layer to represent the actual dates. We add the actual dates layer first, so
    ' it will be the top layer.
    Dim actualLayer As BoxWhiskerLayer
    Set actualLayer = c.addBoxLayer(actualStartDate, actualEndDate, actualColor, "Actual")

    ' Set the bar height to 8 pixels so they will not block the bottom bar
    Call actualLayer.setDataWidth(8)

    ' Add a box-whisker layer to represent the planned schedule date
    Call c.addBoxLayer(startDate, endDate, plannedColor, "Planned").setBorderColor( _
        cd.SameAsMainColor)

    ' Add a legend box on the top right corner (595, 60) of the plot area with 8 pt Arial Bold font.
    ' Use a semi-transparent grey (80808080) background.
    Dim b As LegendBox
    Set b = c.addLegend(595, 60, False, "arialbd.ttf", 8)
    Call b.setAlignment(cd.TopRight)
    Call b.setBackground(&H80808080, -1, 2)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", _
        "title='{xLabel} ({dataSetName}): {top|mmm dd, yyyy} to {bottom|mmm dd, yyyy}'")

End Sub