ChartDirector 6.0 (ASP/COM/VB Edition)

Log Scale Axis


  

This example demonstrates using a log scale axis versus a linear scale axis.

In ChartDirector, log scale axis can be configured using Axis.setLogScale, Axis.setLogScale2 or Axis.setLogScale3.

Source Code Listing

[Web Version (in ASP)] aspdemo\logaxis.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' This script can draw different charts depending on the chartIndex
chartIndex = CInt(Request("img"))

' The data for the chart
data = Array(100, 125, 260, 147, 67)
labels = Array("Mon", "Tue", "Wed", "Thu", "Fri")

' Create a XYChart object of size 200 x 180 pixels
Set c = cd.XYChart(200, 180)

' Set the plot area at (30, 10) and of size 140 x 130 pixels
Call c.setPlotArea(30, 10, 140, 130)

' Ise log scale axis if required
If chartIndex = 1 Then
    Call c.yAxis().setLogScale3()
End If

' Set the labels on the x axis
Call c.xAxis().setLabels(labels)

' Add a color bar layer using the given data. Use a 1 pixel 3D border for the bars.
Call c.addBarLayer3(data).setBorderColor(-1, 1)

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite c.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\logaxis.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The data for the chart
    Dim data()
    data = Array(100, 125, 260, 147, 67)
    Dim labels()
    labels = Array("Mon", "Tue", "Wed", "Thu", "Fri")

    ' Create a XYChart object of size 200 x 180 pixels
    Dim c As XYChart
    Set c = cd.XYChart(200, 180)

    ' Set the plot area at (30, 10) and of size 140 x 130 pixels
    Call c.setPlotArea(30, 10, 140, 130)

    ' Ise log scale axis if required
    If chartIndex = 1 Then
        Call c.yAxis().setLogScale3()
    End If

    ' Set the labels on the x axis
    Call c.xAxis().setLabels(labels)

    ' Add a color bar layer using the given data. Use a 1 pixel 3D border for the bars.
    Call c.addBarLayer3(data).setBorderColor(-1, 1)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", _
        "title='Mileage on {xLabel}: {value} miles'")

End Sub