ChartDirector 6.0 (ASP/COM/VB Edition)

Polygon Bar Shapes




This example demonstrates bars of various polygonal shapes.

ChartDirector supports bars in cylindrical or arbitrary polygonal shapes. This is specified by using BarLayer.setBarShape and BarLayer.setBarShape2. In this example, various polygonal shapes are illustrated.

See Shape Specification on how built-in and custom shapes are defined in ChartDirector.

For demonstration, in this example each bar is of a different shape. BarLayer.setBarShape and BarLayer.setBarShape2 also supports setting the bar shapes based on data groups (or data sets) or data item position. For an example, see Multi-Shape Bar Chart.

Source Code Listing

[Web Version (in ASP)] aspdemo\polygonbar.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The data for the bar chart
data = Array(85, 156, 179.5, 211, 123, 176, 195)

' The labels for the bar chart
labels = Array("Square", "Star(8)", "Polygon(6)", "Cross", "Cross2", "Diamond", "Custom")

' Create a XYChart object of size 500 x 280 pixels.
Set c = cd.XYChart(500, 280)

' Set the plotarea at (50, 40) with alternating light grey (f8f8f8) / white (ffffff) background
Call c.setPlotArea(50, 40, 400, 200, &Hf8f8f8, &Hffffff)

' Add a title to the chart using 14pt Arial Bold Italic font
Call c.addTitle("    Bar Shape Demonstration", "arialbi.ttf", 14)

' Add a multi-color bar chart layer
Set layer = c.addBarLayer3(data)

' Set layer to 3D with 10 pixels 3D depth
Call layer.set3D(10)

' Set bar shape to circular (cylinder)
Call layer.setBarShape(cd.CircleShape)

' Set the first bar (index = 0) to square shape
Call layer.setBarShape(cd.SquareShape, 0, 0)

' Set the second bar to 8-pointed star
Call layer.setBarShape(cd.StarShape(8), 0, 1)

' Set the third bar to 6-sided polygon
Call layer.setBarShape(cd.PolygonShape(6), 0, 2)

' Set the next 3 bars to cross shape, X shape and diamond shape
Call layer.setBarShape(cd.CrossShape(), 0, 3)
Call layer.setBarShape(cd.Cross2Shape(), 0, 4)
Call layer.setBarShape(cd.DiamondShape, 0, 5)

' Set the last bar to a custom shape, specified as an array of (x, y) points in normalized
' coordinates
Call layer.setBarShape2(Array(-500, 0, 0, 500, 500, 0, 500, 1000, 0, 500, -500, 1000), 0, 6)

' Set the labels on the x axis.
Call c.xAxis().setLabels(labels)

' Add a title to the y axis
Call c.yAxis().setTitle("Frequency")

' Add a title to the x axis
Call c.xAxis().setTitle("Shapes")

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite c.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\polygonbar.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The data for the bar chart
    Dim data()
    data = Array(85, 156, 179.5, 211, 123, 176, 195)

    ' The labels for the bar chart
    Dim labels()
    labels = Array("Square", "Star(8)", "Polygon(6)", "Cross", "Cross2", "Diamond", "Custom")

    ' Create a XYChart object of size 500 x 280 pixels.
    Dim c As XYChart
    Set c = cd.XYChart(500, 280)

    ' Set the plotarea at (50, 40) with alternating light grey (f8f8f8) / white (ffffff) background
    Call c.setPlotArea(50, 40, 400, 200, &Hf8f8f8, &Hffffff)

    ' Add a title to the chart using 14pt Arial Bold Italic font
    Call c.addTitle("    Bar Shape Demonstration", "arialbi.ttf", 14)

    ' Add a multi-color bar chart layer
    Dim layer As BarLayer
    Set layer = c.addBarLayer3(data)

    ' Set layer to 3D with 10 pixels 3D depth
    Call layer.set3D(10)

    ' Set bar shape to circular (cylinder)
    Call layer.setBarShape(cd.CircleShape)

    ' Set the first bar (index = 0) to square shape
    Call layer.setBarShape(cd.SquareShape, 0, 0)

    ' Set the second bar to 8-pointed star
    Call layer.setBarShape(cd.StarShape(8), 0, 1)

    ' Set the third bar to 6-sided polygon
    Call layer.setBarShape(cd.PolygonShape(6), 0, 2)

    ' Set the next 3 bars to cross shape, X shape and diamond shape
    Call layer.setBarShape(cd.CrossShape(), 0, 3)
    Call layer.setBarShape(cd.Cross2Shape(), 0, 4)
    Call layer.setBarShape(cd.DiamondShape, 0, 5)

    ' Set the last bar to a custom shape, specified as an array of (x, y) points in normalized
    ' coordinates
    Call layer.setBarShape2(Array(-500, 0, 0, 500, 500, 0, 500, 1000, 0, 500, -500, 1000), 0, 6)

    ' Set the labels on the x axis.
    Call c.xAxis().setLabels(labels)

    ' Add a title to the y axis
    Call c.yAxis().setTitle("Frequency")

    ' Add a title to the x axis
    Call c.xAxis().setTitle("Shapes")

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", "title='{xLabel}: {value}'")

End Sub