ChartDirector 6.0 (ASP/COM/VB Edition)

White Vertical Linear Meters


          

This example demonstrates vertical bar meters in a white coloring scheme.

Source Code Listing

[Web Version (in ASP)] aspdemo\whitevlinearmeter.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' This script can draw different charts depending on the chartIndex
chartIndex = CInt(Request("img"))

' The value to display on the meter
value = 75.35

' Create a LinearMeter object of size 250 x 75 pixels with very light grey (0xeeeeee) backgruond and
' a light grey (0xccccccc) 3-pixel thick rounded frame
Set m = cd.LinearMeter(70, 260, &Heeeeee, &Hcccccc)
Call m.setRoundedFrame(cd.Transparent)
Call m.setThickFrame(3)

' Set the scale region top-left corner at (28, 30), with size of 20 x 196 pixels. The scale labels
' are located on the left (default - implies vertical meter)
Call m.setMeter(28, 30, 20, 196)

' Set meter scale from 0 - 100, with a tick every 10 units
Call m.setScale(0, 100, 10)

' Demostrate different types of color scales and putting them at different positions
smoothColorScale = Array(0, &H6666ff, 25, &H00bbbb, 50, &H00ff00, 75, &Hffff00, 100, &Hff0000)
stepColorScale = Array(0, &H33ff33, 50, &Hffff33, 80, &Hff3333, 100)
highLowColorScale = Array(0, &H6666ff, 70, cd.Transparent, 100, &Hff0000)

If chartIndex = 0 Then
    ' Add the smooth color scale at the default position
    Call m.addColorScale(smoothColorScale)
ElseIf chartIndex = 1 Then
    ' Add the step color scale at the default position
    Call m.addColorScale(stepColorScale)
ElseIf chartIndex = 2 Then
    ' Add the high low scale at the default position
    Call m.addColorScale(highLowColorScale)
ElseIf chartIndex = 3 Then
    ' Add the smooth color scale starting at x = 28 (left of scale) with zero width and ending at x
    ' = 28 with 20 pixels width
    Call m.addColorScale(smoothColorScale, 28, 0, 28, 20)
ElseIf chartIndex = 4 Then
    ' Add the smooth color scale starting at x = 38 (center of scale) with zero width and ending at
    ' x = 28 with 20 pixels width
    Call m.addColorScale(smoothColorScale, 38, 0, 28, 20)
Else
    ' Add the smooth color scale starting at x = 48 (right of scale) with zero width and ending at x
    ' = 28 with 20 pixels width
    Call m.addColorScale(smoothColorScale, 48, 0, 28, 20)
End If

' In this demo, we demostrate pointers of different shapes
If chartIndex < 3 Then
    ' Add a blue (0x0000cc) pointer of default shape at the specified value
    Call m.addPointer(value, &H0000cc)
Else
    ' Add a blue (0x0000cc) pointer of triangular shape the specified value
    Call m.addPointer(value, &H0000cc).setShape(cd.TriangularPointer, 0.7, 0.5)
End If

' Add a title using 8pt Arial Bold font with a border color background
Call m.addTitle("Temp C", "arialbd.ttf", 8, cd.TextColor).setBackground(&Hcccccc)

' Add a text box at the bottom-center. Display the value using white (0xffffff) 8pt Arial Bold font
' on a black (0x000000) background with rounded border.
Set t = m.addText(m.getWidth() / 2, m.getHeight() - 8, m.formatValue(value, "2"), "arialbd.ttf", _
    8, &Hffffff, cd.Bottom)
Call t.setBackground(&H000000)
Call t.setRoundedCorners(3)
Call t.setMargin2(5, 5, 2, 1)

' Output the chart
Response.ContentType = "image/png"
Response.BinaryWrite m.makeChart2(cd.PNG)
Response.End
%>

[Windows Version (in Visual Basic)] vbdemo\whitevlinearmeter.cls
Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The value to display on the meter
    Dim value As Double
    value = 75.35

    ' Create a LinearMeter object of size 250 x 75 pixels with very light grey (0xeeeeee) backgruond
    ' and a light grey (0xccccccc) 3-pixel thick rounded frame
    Dim m As LinearMeter
    Set m = cd.LinearMeter(70, 260, &Heeeeee, &Hcccccc)
    Call m.setRoundedFrame()
    Call m.setThickFrame(3)

    ' Set the scale region top-left corner at (28, 30), with size of 20 x 196 pixels. The scale
    ' labels are located on the left (default - implies vertical meter)
    Call m.setMeter(28, 30, 20, 196)

    ' Set meter scale from 0 - 100, with a tick every 10 units
    Call m.setScale(0, 100, 10)

    ' Demostrate different types of color scales and putting them at different positions
    Dim smoothColorScale()
    smoothColorScale = Array(0, &H6666ff, 25, &H00bbbb, 50, &H00ff00, 75, &Hffff00, 100, &Hff0000)
    Dim stepColorScale()
    stepColorScale = Array(0, &H33ff33, 50, &Hffff33, 80, &Hff3333, 100)
    Dim highLowColorScale()
    highLowColorScale = Array(0, &H6666ff, 70, cd.Transparent, 100, &Hff0000)

    If chartIndex = 0 Then
        ' Add the smooth color scale at the default position
        Call m.addColorScale(smoothColorScale)
    ElseIf chartIndex = 1 Then
        ' Add the step color scale at the default position
        Call m.addColorScale(stepColorScale)
    ElseIf chartIndex = 2 Then
        ' Add the high low scale at the default position
        Call m.addColorScale(highLowColorScale)
    ElseIf chartIndex = 3 Then
        ' Add the smooth color scale starting at x = 28 (left of scale) with zero width and ending
        ' at x = 28 with 20 pixels width
        Call m.addColorScale(smoothColorScale, 28, 0, 28, 20)
    ElseIf chartIndex = 4 Then
        ' Add the smooth color scale starting at x = 38 (center of scale) with zero width and ending
        ' at x = 28 with 20 pixels width
        Call m.addColorScale(smoothColorScale, 38, 0, 28, 20)
    Else
        ' Add the smooth color scale starting at x = 48 (right of scale) with zero width and ending
        ' at x = 28 with 20 pixels width
        Call m.addColorScale(smoothColorScale, 48, 0, 28, 20)
    End If

    ' In this demo, we demostrate pointers of different shapes
    If chartIndex < 3 Then
        ' Add a blue (0x0000cc) pointer of default shape at the specified value
        Call m.addPointer(value, &H0000cc)
    Else
        ' Add a blue (0x0000cc) pointer of triangular shape the specified value
        Call m.addPointer(value, &H0000cc).setShape(cd.TriangularPointer, 0.7, 0.5)
    End If

    ' Add a title using 8pt Arial Bold font with a border color background
    Call m.addTitle("Temp C", "arialbd.ttf", 8, cd.TextColor).setBackground(&Hcccccc)

    ' Add a text box at the bottom-center. Display the value using white (0xffffff) 8pt Arial Bold
    ' font on a black (0x000000) background with rounded border.
    Dim t As ChartDirector.TextBox
    Set t = m.addText(m.getWidth() / 2, m.getHeight() - 8, m.formatValue(value, "2"), _
        "arialbd.ttf", 8, &Hffffff, cd.Bottom)
    Call t.setBackground(&H000000)
    Call t.setRoundedCorners(3)
    Call t.setMargin2(5, 5, 2, 1)

    ' Output the chart
    Set viewer.Picture = m.makePicture()

End Sub