<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// Function to create the demo charts
function createChart(chartIndex)
{
    // Declare local variables
    var value = 0;
    var m = 0;
    var smoothColorScale = 0;
    var stepColorScale = 0;
    var highLowColorScale = 0;
    var highColorScale = 0;
    var t = 0;

    // The value to display on the meter
    value = 75.35;

    // Create a LinearMeter object of size 260 x 80 pixels with black background and rounded corners
    m = cd.LinearMeter(260, 80, "0x000000");
    m.setRoundedFrame(cd.Transparent);

    // Set the default text and line colors to white (0xffffff)
    m.setColor(cd.TextColor, "0xffffff");
    m.setColor(cd.LineColor, "0xffffff");

    // Set the scale region top-left corner at (15, 24), with size of 228 x 20 pixels. The scale
    // labels are located on the top (implies horizontal meter)
    m.setMeter(15, 24, 228, 20, cd.Top);

    // Set meter scale from 0 - 100, with a tick every 10 units
    m.setScale(0, 100, 10);

    // Demostrate different types of color scales
    smoothColorScale = Array(0, "0x0000ff", 25, "0x0088ff", 50, "0x00ff00", 75, "0xdddd00", 100,
        "0xff0000");
    stepColorScale = Array(0, "0x00dd00", 50, "0xffff00", 80, "0xff3333", 100);
    highLowColorScale = Array(0, "0x0000ff", 40, cd.Transparent, 60, cd.Transparent, 100, "0xff0000"
        );
    highColorScale = Array(70, cd.Transparent, 100, "0xff0000");

    if (chartIndex EQ 0) {
        // Add a blue (0x0088ff) bar from 0 to value with glass effect and 4 pixel rounded corners
        m.addBar(0, value, "0x0088ff", cd.glassEffect(cd.NormalGlare, cd.Top), 4);
        // Add a 5-pixel thick smooth color scale at y = 48 (below the meter scale)
        m.addColorScale(smoothColorScale, 48, 5);
    } else if (chartIndex EQ 1) {
        // Add a purple (0xaa66ff) bar from 0 to value
        m.addBar(0, value, "0xaa66ff");
        // Add a 4 pixel thick purple (0x880088) frame
        m.setThickFrame(4, "0x880088");
        // Add a 5-pixel thick high/low color scale at y = 48 (below the meter scale)
        m.addColorScale(highLowColorScale, 48, 5);
    } else if (chartIndex EQ 2) {
         // Add a green (0x00ee00) bar from 0 to value with right side soft lighting effect and 4
         // pixel rounded corners
        m.addBar(0, value, "0x00ee00", cd.softLighting(cd.Right), 4);
        // Add a 5-pixel thick step color scale at y = 48 (below the meter scale)
        m.addColorScale(stepColorScale, 48, 5);
    } else if (chartIndex EQ 3) {
          // Add an orange (0xff8800) bar from 0 to value with cylinder lighting effect
        m.addBar(0, value, "0xff8800", cd.cylinderEffect());
        // Add a 4 pixel thick brown (0xbb5500) frame
        m.setThickFrame(4, "0xbb5500");
        // Add a 5-pixel thick high only color scale at y = 48 (below the meter scale)
        m.addColorScale(highColorScale, 48, 5);
    } else if (chartIndex EQ 4) {
         // Add a magneta (0xdd00dd) bar from 0 to value with top side soft lighting effect and 4
         // pixel rounded corners
        m.addBar(0, value, "0xdd00dd", cd.softLighting(cd.Top), 4);
        // Add a 5-pixel thick smooth color scale at y = 48 (below the meter scale)
        m.addColorScale(smoothColorScale, 48, 5);
    } else {
         // Add a red (0xff0000) bar from 0 to value with bar lighting effect
        m.addBar(0, value, "0xff0000", cd.barLighting());
        // Add a 4 pixel thick red (0xaa0000) frame
        m.setThickFrame(4, "0xaa0000");
           // Add a 5-pixel thick high/low color scale at y = 48 (below the meter scale)
        m.addColorScale(highLowColorScale, 48, 5);
    }

    // Add a label left aligned to (12, 65) using 8pt Arial Bold font
    m.addText(12, 65, "Temperature C", "Arial Bold", 8, cd.TextColor, cd.Left);

    // Add a text box right aligned to (243, 65). Display the value using white (0xffffff) 8pt Arial
    // Bold font on a black (0x000000) background with depressed dark grey (0x333333) rounded
    // border.
    t = m.addText(243, 65, m.formatValue(value, "2"), "Arial", 8, "0xffffff", cd.Right);
    t.setBackground("0x000000", "0x333333", -1);
    t.setRoundedCorners(3);

    // Output the chart
    return m.makeSession(GetPageContext(), "chart" & chartIndex);
}

chart0URL = createChart(0);
chart1URL = createChart(1);
chart2URL = createChart(2);
chart3URL = createChart(3);
chart4URL = createChart(4);
chart5URL = createChart(5);

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Black Horizontal Bar Meters
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart0URL#" />
<img src="getchart.cfm?#chart1URL#" />
<img src="getchart.cfm?#chart2URL#" />
<img src="getchart.cfm?#chart3URL#" />
<img src="getchart.cfm?#chart4URL#" />
<img src="getchart.cfm?#chart5URL#" />
</cfoutput>
</body>
</html>