Horizontal Bar Meter

This example demonstrates the basic steps in creating a horizontal bar meter.

A horizontal bar meter can be created using the following steps:

Create a LinearMeter object using LinearMeter.LinearMeter, optionally specify the background and border colors and whether to use rounded and/or thick frames..
Specify the size of the meter scale and the orientation of the scale labels using LinearMeter.setMeter. In this example, the scale labels are positioned at the top of the meter scale. This automatically implies the meter as horizontal.
Set the numeric scale of the meter using BaseMeter.setScale.
Optionally add a color scale to the meter using BaseMeter.addColorScale. Whereas the meter scale displays the values with text labels, a color scale represents the values with different colors.
Add a bar to the meter using LinearMeter.addBar. In this example, the bar is added with a glass shading effect specified using ChartDirector.CFChart.glassEffect.

[File: cfdemo/hbarmeter.cfm]

<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// The value to display on the meter
value = 75.35;

// Create an LinearMeter object of size 260 x 66 pixels with a very light grey (0xeeeeee)
// background, and a rounded 3-pixel thick light grey (0xaaaaaa) border
m = cd.LinearMeter(260, 66, "0xeeeeee", "0xaaaaaa");
m.setRoundedFrame(cd.Transparent);
m.setThickFrame(3);

// Set the scale region top-left corner at (18, 24), with size of 222 x 20 pixels. The scale labels
// are located on the top (implies horizontal meter)
m.setMeter(18, 24, 222, 20, cd.Top);

// Set meter scale from 0 - 100, with a tick every 10 units
m.setScale(0, 100, 10);

// Add a 5-pixel thick smooth color scale to the meter at y = 48 (below the meter scale)
smoothColorScale = Array(0, "0x0000ff", 25, "0x0088ff", 50, "0x00ff00", 75, "0xffff00", 100,
    "0xff0000");
m.addColorScale(smoothColorScale, 48, 5);

// Add a light blue (0x0088ff) bar from 0 to the data value with glass effect and 4 pixel rounded
// corners
m.addBar(0, value, "0x0088ff", cd.glassEffect(cd.NormalGlare, cd.Top), 4);

// Output the chart
chart1URL = m.makeSession(GetPageContext(), "chart1");

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Horizontal Bar Meter
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart1URL#" />
</cfoutput>
</body>
</html>