Scattered Data Contour Chart

[Web Version (in ASP)] aspdemo\scattercontour.asp

<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The (x, y, z) coordinates of the scattered data
dataX = Array(0.5, 1.9, 4.9, 1.0, 8.9, 9.8, 5.9, 2.9, 6.8, 9.0, 0.0, 8.9, 1.9, 4.8, 2.4, 3.4, 7.9, _
    7.5, 4.8, 7.5, 9.5, 0.4, 8.9, 0.9, 5.4, 9.4, 2.9, 8.9, 0.9, 8.9, 10.0, 1.0, 6.8, 3.8, 9.0, _
    5.3, 6.4, 4.9, 4.5, 2.0, 5.4, 0.0, 10.0, 3.9, 5.4, 5.9, 5.8, 0.3, 4.4, 8.3)
dataY = Array(3.3, 3.0, 0.7, 1.0, 9.3, 4.5, 8.4, 0.1, 0.8, 0.1, 9.3, 1.8, 4.3, 1.3, 2.3, 5.4, 6.9, _
    9.0, 9.8, 7.5, 1.8, 1.4, 4.5, 7.8, 3.8, 4.0, 2.9, 2.4, 3.9, 2.9, 2.3, 9.3, 2.0, 3.4, 4.8, 2.3, _
    3.4, 2.3, 1.5, 7.8, 4.5, 0.9, 6.3, 2.4, 6.9, 2.8, 1.3, 2.9, 6.4, 6.3)
dataZ = Array(6.6, 12.5, 7.4, 6.2, 9.6, 13.6, 19.9, 2.2, 6.9, 3.4, 8.7, 8.4, 7.8, 8.0, 9.4, 11.9, _
    9.6, 15.7, 12.0, 13.3, 9.6, 6.4, 9.0, 6.9, 4.6, 9.7, 10.6, 9.2, 7.0, 6.9, 9.7, 8.6, 8.0, 13.6, _
    13.2, 5.9, 9.0, 3.2, 8.3, 9.7, 8.2, 6.1, 8.7, 5.6, 14.9, 9.8, 9.3, 5.1, 10.8, 9.8)

' Create a XYChart object of size 450 x 540 pixels
Set c = cd.XYChart(450, 540)

' Add a title to the chart using 15 points Arial Italic font
Call c.addTitle("      Contour Chart with Scattered Data", "Arial Italic", 15)

' Set the plotarea at (65, 40) and of size 360 x 360 pixels. Use semi-transparent black (c0000000)
' for both horizontal and vertical grid lines
Call c.setPlotArea(65, 40, 360, 360, -1, -1, -1, &Hc0000000, -1)

' Set x-axis and y-axis title using 12 points Arial Bold Italic font
Call c.xAxis().setTitle("X-Axis Title Place Holder", "Arial Bold Italic", 10)
Call c.yAxis().setTitle("Y-Axis Title Place Holder", "Arial Bold Italic", 10)

' Set x-axis and y-axis labels to use Arial Bold font
Call c.xAxis().setLabelStyle("Arial Bold")
Call c.yAxis().setLabelStyle("Arial Bold")

' When x-axis and y-axis color to transparent
Call c.xAxis().setColors(cd.Transparent)
Call c.yAxis().setColors(cd.Transparent)

' Add a scatter layer to the chart to show the position of the data points. Disable the image map
' for the scatter layer. We will use the contour layer to provide the tooltip.
Call c.addScatterLayer(dataX, dataY, "", cd.Cross2Shape(0.2), 7, &H000000).setHTMLImageMap( _
    "{disable}")

' Add a contour layer using the given data
Set layer = c.addContourLayer(dataX, dataY, dataZ)

' Move the grid lines in front of the contour layer
Call c.getPlotArea().moveGridBefore(layer)

' Add a color axis (the legend) in which the top center is anchored at (245, 455). Set the length to
' 330 pixels and the labels on the top side.
Set cAxis = layer.setColorAxis(245, 455, cd.TopCenter, 330, cd.Top)

' Add a bounding box to the color axis using the default line color as border.
Call cAxis.setBoundingBox(cd.Transparent, cd.LineColor)

' Add a title to the color axis using 12 points Arial Bold Italic font
Call cAxis.setTitle("Color Legend Title Place Holder", "Arial Bold Italic", 10)

' Set color axis labels to use Arial Bold font
Call cAxis.setLabelStyle("Arial Bold")

' Set the color axis range as 0 to 20, with a step every 2 units
Call cAxis.setLinearScale(0, 20, 2)

' Output the chart
Set viewer = cd.WebChartViewer(Request, "chart1")
Call viewer.setChart(c, cd.SVG)

' Include CDML tool tip for the chart.
viewer.ImageMap = c.getHTMLImageMap("", "", _
    "title='<*cdml*><*b*>X: {x|2}<*br*>Y: {y|2}<*br*>Z: {z|2}'")

' Output Javascript chart model to support contour chart tooltips
viewer.ChartModel = c.getJsChartModel()
%>

<!DOCTYPE html>
<html>
<head>
    <title>Scattered Data Contour Chart</title>
    <!-- Include ChartDirector Javascript Library to support chart interactions -->
    <script type="text/javascript" src="cdjcv.js"></script>
</head>
<body style="margin:5px 0px 0px 5px">
    <div style="font:bold 18pt verdana;">
        Scattered Data Contour Chart
    </div>
    <hr style="border:solid 1px #000080; background:#000080" />
    <div style="font:10pt verdana; margin-bottom:1.5em">
        <a href="viewsource.asp?file=<%= Request("SCRIPT_NAME") %>">View Chart Source Code</a>
    </div>
    <!-- ****** Here is the chart image ****** -->
    <%= viewer.renderHTML() %>
</body>
</html>

[Windows Version (in Visual Basic)] vbdemo\scattercontour.cls

Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The (x, y, z) coordinates of the scattered data
    Dim dataX()
    dataX = Array(0.5, 1.9, 4.9, 1.0, 8.9, 9.8, 5.9, 2.9, 6.8, 9.0, 0.0, 8.9, 1.9, 4.8, 2.4, 3.4, _
        7.9, 7.5, 4.8, 7.5, 9.5, 0.4, 8.9, 0.9, 5.4, 9.4, 2.9, 8.9, 0.9, 8.9, 10.0, 1.0, 6.8, 3.8, _
        9.0, 5.3, 6.4, 4.9, 4.5, 2.0, 5.4, 0.0, 10.0, 3.9, 5.4, 5.9, 5.8, 0.3, 4.4, 8.3)
    Dim dataY()
    dataY = Array(3.3, 3.0, 0.7, 1.0, 9.3, 4.5, 8.4, 0.1, 0.8, 0.1, 9.3, 1.8, 4.3, 1.3, 2.3, 5.4, _
        6.9, 9.0, 9.8, 7.5, 1.8, 1.4, 4.5, 7.8, 3.8, 4.0, 2.9, 2.4, 3.9, 2.9, 2.3, 9.3, 2.0, 3.4, _
        4.8, 2.3, 3.4, 2.3, 1.5, 7.8, 4.5, 0.9, 6.3, 2.4, 6.9, 2.8, 1.3, 2.9, 6.4, 6.3)
    Dim dataZ()
    dataZ = Array(6.6, 12.5, 7.4, 6.2, 9.6, 13.6, 19.9, 2.2, 6.9, 3.4, 8.7, 8.4, 7.8, 8.0, 9.4, _
        11.9, 9.6, 15.7, 12.0, 13.3, 9.6, 6.4, 9.0, 6.9, 4.6, 9.7, 10.6, 9.2, 7.0, 6.9, 9.7, 8.6, _
        8.0, 13.6, 13.2, 5.9, 9.0, 3.2, 8.3, 9.7, 8.2, 6.1, 8.7, 5.6, 14.9, 9.8, 9.3, 5.1, 10.8, _
        9.8)

    ' Create a XYChart object of size 450 x 540 pixels
    Dim c As XYChart
    Set c = cd.XYChart(450, 540)

    ' Add a title to the chart using 15 points Arial Italic font
    Call c.addTitle("      Contour Chart with Scattered Data", "ariali.ttf", 15)

    ' Set the plotarea at (65, 40) and of size 360 x 360 pixels. Use semi-transparent black
    ' (c0000000) for both horizontal and vertical grid lines
    Call c.setPlotArea(65, 40, 360, 360, -1, -1, -1, &Hc0000000, -1)

    ' Set x-axis and y-axis title using 12 points Arial Bold Italic font
    Call c.xAxis().setTitle("X-Axis Title Place Holder", "arialbi.ttf", 10)
    Call c.yAxis().setTitle("Y-Axis Title Place Holder", "arialbi.ttf", 10)

    ' Set x-axis and y-axis labels to use Arial Bold font
    Call c.xAxis().setLabelStyle("arialbd.ttf")
    Call c.yAxis().setLabelStyle("arialbd.ttf")

    ' When x-axis and y-axis color to transparent
    Call c.xAxis().setColors(cd.Transparent)
    Call c.yAxis().setColors(cd.Transparent)

    ' Add a scatter layer to the chart to show the position of the data points
    Call c.addScatterLayer(dataX, dataY, "", cd.Cross2Shape(0.2), 7, &H000000)

    ' Add a contour layer using the given data
    Dim layer As ContourLayer
    Set layer = c.addContourLayer(dataX, dataY, dataZ)

    ' Move the grid lines in front of the contour layer
    Call c.getPlotArea().moveGridBefore(layer)

    ' Add a color axis (the legend) in which the top center is anchored at (245, 455). Set the
    ' length to 330 pixels and the labels on the top side.
    Dim cAxis As ColorAxis
    Set cAxis = layer.setColorAxis(245, 455, cd.TopCenter, 330, cd.Top)

    ' Add a bounding box to the color axis using the default line color as border.
    Call cAxis.setBoundingBox(cd.Transparent, cd.LineColor)

    ' Add a title to the color axis using 12 points Arial Bold Italic font
    Call cAxis.setTitle("Color Legend Title Place Holder", "arialbi.ttf", 10)

    ' Set color axis labels to use Arial Bold font
    Call cAxis.setLabelStyle("arialbd.ttf")

    ' Set the color axis range as 0 to 20, with a step every 2 units
    Call cAxis.setLinearScale(0, 20, 2)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

End Sub